      Subroutine Hlxset(ssbond, sssumm, summpl, hlxpos, hlxsz, hlxch,   HLXS001
     &                  altch,  seqlen)                                 HLXS002
c                                                                       HLXS003
c     go through the bond tables and note any helices into the          HLXS004
c     summary line                                                      HLXS005
c                                                                       HLXS006
      include 'sstruc.par'                                              HLXS007
      character*1 ssbond(nstruc,maxres), sssumm(maxres), hlxch, altch,  HLXS008
     &            summpl(maxres)                                        HLXS009
      integer     hlxpos, hlxsz, seqlen                                 HLXS010
                                                                        HLXS011
      integer     nxres, nxsym                                          HLXS012
                                                                        HLXS013
      do 1000, nxres = 2, seqlen - hlxsz                                HLXS014
      if (ssbond(hlxpos,nxres) .eq. bndbeg .or.                         HLXS015
     &   ssbond(hlxpos,nxres) .eq. bndbth) then                         HLXS016
         if (ssbond(hlxpos,nxres-1) .eq. bndbeg .or.                    HLXS017
     &      ssbond(hlxpos,nxres-1) .eq. bndbth) then                    HLXS018
            do 500, nxsym = 0, hlxsz - 1                                HLXS019
            if (sssumm(nxres+nxsym) .eq. space)                         HLXS020
     &         sssumm(nxres+nxsym) = hlxch                              HLXS021
            if (summpl(nxres+nxsym) .eq. space .OR.                     HLXS022
     &         summpl(nxres+nxsym) .eq. altch)                          HLXS023
     &         summpl(nxres+nxsym) = hlxch                              HLXS024
  500       continue                                                    HLXS025
            if (summpl(nxres-1) .eq. space) summpl(nxres-1) = altch     HLXS026
            if (summpl(nxres+hlxsz) .eq. space)                         HLXS027
     &             summpl(nxres+hlxsz) = altch                          HLXS028
         end if                                                         HLXS029
      end if                                                            HLXS030
 1000 continue                                                          HLXS031
      END                                                               HLXS032
